diff mbox series

[oe,meta-oe,v2] cpupower: add a new recipe

Message ID 20170921080833.32623-1-fathi.boudra@linaro.org
State Accepted
Commit 9de8ce7f3ae6f4ded76496ada28ac6c3c4c22122
Headers show
Series [oe,meta-oe,v2] cpupower: add a new recipe | expand

Commit Message

Fathi Boudra Sept. 21, 2017, 8:08 a.m. UTC 
cpupower is a tool to show and set processor power related values.
In addition, it allows to run in-kernel selftests intel_pstate test.

The recipe is based on the initial work from Roy Li <rongqing.li@windriver.com>:
https://patchwork.openembedded.org/patch/118911/

Signed-off-by: Fathi Boudra <fathi.boudra@linaro.org>

---
 meta-oe/recipes-kernel/cpupower/cpupower.bb | 36 +++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 meta-oe/recipes-kernel/cpupower/cpupower.bb

-- 
2.14.1

-- 
_______________________________________________
Openembedded-devel mailing list
Openembedded-devel@lists.openembedded.org
http://lists.openembedded.org/mailman/listinfo/openembedded-devel
diff mbox series

Patch

diff --git a/meta-oe/recipes-kernel/cpupower/cpupower.bb b/meta-oe/recipes-kernel/cpupower/cpupower.bb
new file mode 100644
index 000000000..c963c8ef9
--- /dev/null
+++ b/meta-oe/recipes-kernel/cpupower/cpupower.bb
@@ -0,0 +1,36 @@ 
+SUMMARY = "Shows and sets processor power related values"
+DESCRIPTION = "cpupower is a collection of tools to examine and tune power \
+saving related features of your processor."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+DEPENDS = "pciutils"
+PROVIDES = "virtual/cpupower"
+
+inherit kernelsrc kernel-arch
+
+do_populate_lic[depends] += "virtual/kernel:do_patch"
+
+EXTRA_OEMAKE = "-C ${S}/tools/power/cpupower O=${B} CROSS=${TARGET_PREFIX} CC="${CC}" LD="${LD}" AR=${AR} ARCH=${ARCH}"
+
+do_configure[depends] += "virtual/kernel:do_shared_workdir"
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+    oe_runmake DESTDIR=${D} install
+    # Do not ship headers
+    rm -rf ${D}${includedir}
+    chown -R root:root ${D}
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+RDEPENDS_${PN} = "bash"
+
+python do_package_prepend() {
+    d.setVar('PKGV', d.getVar("KERNEL_VERSION", True).split("-")[0])
+}
+
+B = "${WORKDIR}/${BPN}-${PV}"